01)対話する　display dialog

確認
display dialogの出し方と何を入力したか調べます。

display dialog "こんにちは" --キャンセルをクッリクすると処理終了

display dialog は変数を単に表示するだけで今入っている変数の値を確認するデバッグ用としてつかえる。

入力

set myAnswer to display dialog "入力してください" default answer "ここに入力"
set inputStr to text returned of myAnswer
display dialog "入力したのは「" & inputStr & "」ですね"

入力された文字は変数myAnswerの中に入っている。text returnedで取り出す事が出来る。

ボタン

set myAnswer to display dialog "食べたいものは" buttons {"くり", "こめ", "つけもの"}
set selectedBtn to button returned of myAnswer
display dialog "クリックしたのは「" & selectedBtn & "」ですね"

押されたボタンも変数myAnswerに入っている。こちらはbutton returnedで取り出す。

入力とボタン

set myAnswer to display dialog "ページ数" default answer "1" buttons {"縦組", "横組"}
set inputStr to text returned of myAnswer
set selectedBtn to button returned of myAnswer
display dialog "ページ数が" & inputStr & "ページで" & selectedBtn & "ですね"

入力した文字と押されたボタン両方を調べる事も出来る。

選択

set mySelect to choose from list {"りんご", "みかん", "ぶどう"} with prompt ¬
		"選択してください"--¬は実際には改行を入れない
display dialog item 1 of mySelect--listで返ってくるのでitem 1 で取り出す。

こちらはリストから選択する。さらに下記はリストから複数選択可能にしたもの。どちらも値はリストで返ってくるので要注意。

set mySelectList to choose from list {"りんご", "みかん", "ぶどう"} with prompt ¬
		"選択してください" with multiple selections allowed --複数選択可
repeat with mySelect in mySelectList --listの中のitem分繰り返す
	display dialog mySelect
end repeat